تابع VLOOKUP در اکسل – راهنمای مبتدیان: نحو و مثال

امروز ما مجموعه ای از مقالات را شروع می کنیم که یکی از مفیدترین ویژگی های اکسل - را شرح می دهد VPR (VLOOKUP). این عملکرد، در عین حال، یکی از پیچیده ترین و کم درک ترین است.

در این آموزش در VPR من سعی خواهم کرد که اصول اولیه را به ساده ترین شکل ممکن بیان کنم تا فرآیند یادگیری را تا حد امکان برای کاربران بی تجربه روشن کنم. علاوه بر این، چندین مثال را با فرمول های اکسل مطالعه خواهیم کرد که رایج ترین موارد استفاده برای تابع را نشان می دهد VPR.

• شرح کلی و نحو
• نمونه های VLOOKUP
  • نحوه استفاده از VLOOKUP برای جستجو در برگه اکسل دیگر
  • با VLOOKUP در کتاب کار دیگری جستجو کنید
  • نحوه استفاده از محدوده یا جدول نامگذاری شده در فرمول ها با VLOOKUP
  • استفاده از Wildcards در فرمول های VLOOKUP
• مطابقت دقیق یا تقریبی در تابع VLOOKUP
• VLOOKUP در اکسل - باید این را به خاطر بسپارید!

تابع VLOOKUP در اکسل - توضیحات کلی و نحو

پس آن چیست VPR? خوب، اول از همه، این یک تابع اکسل است. او چه کار می کند؟ مقداری را که مشخص کرده‌اید جستجو می‌کند و مقدار مربوطه را از ستون دیگر برمی‌گرداند. از نظر فنی، VPR مقدار را در ستون اول محدوده داده شده جستجو می کند و نتیجه را از ستون دیگری در همان ردیف برمی گرداند.

در رایج ترین برنامه، تابع VPR پایگاه داده را برای یک شناسه منحصربفرد جستجو می کند و برخی از اطلاعات مربوط به آن را از پایگاه داده استخراج می کند.

حرف اول در نام تابع VPR (VLOOKUP) یعنی Вعمودی (Vعمودی). با آن می توانید تشخیص دهید VPR از جانب GPR (HLOOKUP)، که یک مقدار را در ردیف بالای یک محدوده جستجو می کند Гافقی (Hبه صورت افقی).

عملکرد VPR موجود در Excel 2013، Excel 2010، Excel 2007، Excel 2003، Excel XP و Excel 2000.

نحو تابع VLOOKUP

عملکرد VPR (VLOOKUP) دارای نحو زیر است:

VLOOKUP(lookup_value,table_array,col_index_num,[range_lookup])

ВПР(искомое_значение;таблица;номер_столбца;[интервальный_просмотр])

همانطور که می بینید، یک تابع VPR در مایکروسافت اکسل 4 گزینه (یا آرگومان) دارد. سه مورد اول اجباری است، آخرین مورد اختیاری است.

• lookup_value (lookup_value) - مقداری که باید جستجو کنید. این می تواند یک مقدار (عدد، تاریخ، متن) یا یک مرجع سلول (شامل مقدار جستجو) یا مقداری باشد که توسط برخی دیگر از تابع های اکسل برگردانده شده است. به عنوان مثال، این فرمول به دنبال مقدار خواهد بود 40:

  =VLOOKUP(40,A2:B15,2)

  =ВПР(40;A2:B15;2)

اگر مقدار جستجو کمتر از کوچکترین مقدار در ستون اول محدوده مورد جستجو باشد، تابع VPR یک خطا گزارش خواهد کرد #AT (#N/A).

• آرایه جدولی (جدول) - دو یا چند ستون داده. به یاد داشته باشید، تابع VPR همیشه به دنبال مقدار در ستون اول محدوده ارائه شده در آرگومان می گردد آرایه جدولی (جدول). محدوده قابل مشاهده می تواند حاوی داده های مختلفی باشد، مانند متن، تاریخ، اعداد، بولی. تابع غیر حساس به حروف بزرگ و کوچک است، به این معنی که حروف بزرگ و کوچک یکسان در نظر گرفته می شوند. بنابراین فرمول ما به دنبال مقدار خواهد بود 40 در سلول ها از A2 به A15، زیرا A اولین ستون از محدوده A2:B15 است که در آرگومان داده شده است آرایه جدولی (جدول):

  =VLOOKUP(40,A2:B15,2)

  =ВПР(40;A2:B15;2)

• col_index_num (column_number) تعداد ستونی در محدوده داده شده است که از آن مقدار در ردیف یافت شده برگردانده می شود. سمت چپ ترین ستون در محدوده داده شده است 1، ستون دوم است 2، ستون سوم است 3 و غیره اکنون می توانید کل فرمول را بخوانید:

  =VLOOKUP(40,A2:B15,2)

  =ВПР(40;A2:B15;2)

  فرمول به دنبال ارزش 40 در محدوده A2: A15 و مقدار مربوطه را از ستون B برمی گرداند (زیرا B دومین ستون در محدوده A2:B15 است).

اگر ارزش استدلال col_index_num (شماره_ستون) کمتر از 1سپس VPR یک خطا گزارش خواهد کرد #ارزش! (#ارزش!). و اگر بیشتر از تعداد ستون های محدوده باشد آرایه جدولی (جدول)، تابع یک خطا برمی گرداند #مرجع! (#ارتباط دادن!).

• range_lookup (range_lookup) - تعیین می کند که به دنبال چه چیزی باشید:
  • مطابقت دقیق، آرگومان باید برابر باشد نادرست (نادرست)؛
  • مطابقت تقریبی، آرگومان برابر است کد واقعی (درست است) یا اصلا مشخص نشده است.

  این پارامتر اختیاری است، اما بسیار مهم است. در ادامه این آموزش در VPR من چند نمونه به شما نشان خواهم داد که نحوه نوشتن فرمول برای یافتن تطابق دقیق و تقریبی را توضیح می دهد.

نمونه های VLOOKUP

من امیدوارم عملکرد VPR برای شما کمی واضح تر شود حال بیایید به چند مورد استفاده نگاه کنیم VPR در فرمول هایی با داده های واقعی

نحوه استفاده از VLOOKUP برای جستجو در برگه اکسل دیگر

در عمل، فرمول هایی با یک تابع VPR به ندرت برای جستجوی داده ها در یک کاربرگ استفاده می شود. بیشتر اوقات، شما به دنبال جستجو و بازیابی مقادیر مربوطه از یک برگه دیگر هستید.

به منظور استفاده از VPR، در یک برگه دیگر مایکروسافت اکسل جستجو کنید، باید در آرگومان آرایه جدولی (جدول) نام برگه را با علامت تعجب و به دنبال آن محدوده ای از سلول ها مشخص کنید. به عنوان مثال، فرمول زیر نشان می دهد که محدوده A2: B15 در برگه ای به نام است Sheet2.

=VLOOKUP(40,Sheet2!A2:B15,2)

=ВПР(40;Sheet2!A2:B15;2)

البته لازم نیست نام برگه به ​​صورت دستی وارد شود. فقط شروع به تایپ فرمول کنید، و زمانی که بحث به میان می آید آرایه جدولی (جدول)، به صفحه مورد نظر بروید و محدوده مورد نظر سلول ها را با ماوس انتخاب کنید.

فرمول نشان داده شده در تصویر زیر به دنبال متن "محصول 1" در ستون A (این ستون اول از محدوده A1:B2 است) در یک کاربرگ است. قیمت.

=VLOOKUP("Product 1",Prices!$A$2:$B$9,2,FALSE)

=ВПР("Product 1";Prices!$A$2:$B$9;2;ЛОЖЬ)

لطفاً به یاد داشته باشید که هنگام جستجوی یک مقدار متن، باید آن را در علامت نقل قول («») قرار دهید، همانطور که معمولاً در فرمول‌های اکسل انجام می‌شود.

برای استدلال آرایه جدولی (جدول) مطلوب است که همیشه از ارجاعات مطلق (با علامت $) استفاده شود. در این حالت، هنگام کپی کردن فرمول در سلول های دیگر، محدوده جستجو بدون تغییر باقی می ماند.

با VLOOKUP در کتاب کار دیگری جستجو کنید

برای عملکرد VPR بین دو کتاب اکسل کار می شود، باید نام کتاب کار را قبل از نام برگه در کروشه مربع مشخص کنید.

به عنوان مثال، در زیر فرمولی است که به دنبال مقدار است 40 روی ورق Sheet2 در کتاب Numbers.xlsx:

=VLOOKUP(40,[Numbers.xlsx]Sheet2!A2:B15,2)

=ВПР(40;[Numbers.xlsx]Sheet2!A2:B15;2)

در اینجا ساده ترین راه برای ایجاد فرمول در اکسل است VPRکه به کتاب کار دیگری پیوند دارد:

1. هر دو کتاب را باز کنید. این مورد نیاز نیست، اما ایجاد یک فرمول از این طریق آسان تر است. شما نمی خواهید نام کتاب کار را به صورت دستی وارد کنید، درست است؟ علاوه بر این، شما را از اشتباهات تایپی تصادفی محافظت می کند.
2. شروع به تایپ یک تابع کنید VPRو وقتی بحث به میان می آید آرایه جدولی (جدول)، به کتاب کار دیگری بروید و محدوده جستجوی مورد نیاز را در آن انتخاب کنید.

اسکرین شات زیر فرمول را نشان می دهد که جستجو بر روی یک محدوده در کتاب کار تنظیم شده است PriceList.xlsx روی ورق قیمت.

عملکرد VPR حتی زمانی که کتاب کار جستجو شده را ببندید و مسیر کامل فایل کتاب کار در نوار فرمول ظاهر شود، مانند تصویر زیر، کار خواهد کرد:

اگر نام کتاب کار یا برگه دارای فاصله باشد، باید با حروف آپاستروف محصور شود:

=VLOOKUP(40,'[Numbers.xlsx]Sheet2'!A2:B15,2)

=ВПР(40;'[Numbers.xlsx]Sheet2'!A2:B15;2)

نحوه استفاده از محدوده یا جدول نامگذاری شده در فرمول ها با VLOOKUP

اگر قصد دارید از همان محدوده جستجو در چندین عملکرد استفاده کنید VPR، می توانید یک محدوده با نام ایجاد کنید و نام آن را به عنوان آرگومان در فرمول وارد کنید آرایه جدولی (جدول).

برای ایجاد یک محدوده با نام، کافی است سلول ها را انتخاب کرده و نام مناسب را در فیلد وارد کنید نام، در سمت چپ نوار فرمول.

اکنون می توانید فرمول زیر را برای یافتن قیمت یک محصول یادداشت کنید 1 محصول:

=VLOOKUP("Product 1",Products,2)

=ВПР("Product 1";Products;2)

اکثر نام های محدوده برای کل کتاب کار اکسل کار می کنند، بنابراین نیازی به تعیین نام برگه برای آرگومان نیست. آرایه جدولی (جدول)، حتی اگر فرمول و محدوده جستجو در کاربرگ های مختلف باشد. اگر آنها در کتاب های کاری مختلف هستند، قبل از نام محدوده باید نام کتاب کار را مشخص کنید، به عنوان مثال، مانند این:

=VLOOKUP("Product 1",PriceList.xlsx!Products,2)

=ВПР("Product 1";PriceList.xlsx!Products;2)

بنابراین فرمول بسیار واضح تر به نظر می رسد، موافقید؟ همچنین، استفاده از محدوده های نامگذاری شده جایگزین خوبی برای مراجع مطلق است زیرا با کپی کردن فرمول در سلول های دیگر، محدوده نامگذاری شده تغییر نمی کند. این بدان معنی است که می توانید مطمئن باشید که محدوده جستجو در فرمول همیشه درست باقی می ماند.

اگر محدوده ای از سلول ها را با استفاده از دستور به یک صفحه گسترده اکسل کامل تبدیل کنید جدول (جدول) زبانه الحاق (درج کنید)، سپس وقتی محدوده ای را با ماوس انتخاب می کنید، مایکروسافت اکسل به طور خودکار نام ستون ها (یا نام جدول را در صورت انتخاب کل جدول) به فرمول اضافه می کند.

فرمول تمام شده چیزی شبیه به این خواهد بود:

=VLOOKUP("Product 1",Table46[[Product]:[Price]],2)

=ВПР("Product 1";Table46[[Product]:[Price]];2)

یا شاید هم مثل این:

=VLOOKUP("Product 1",Table46,2)

=ВПР("Product 1";Table46;2)

هنگام استفاده از محدوده‌های نام‌گذاری شده، بدون توجه به جایی که تابع را کپی می‌کنید، پیوندها به همان سلول‌ها اشاره می‌کنند VPR در کتاب کار

استفاده از Wildcards در فرمول های VLOOKUP

مانند بسیاری از توابع دیگر، VPR می توانید از کاراکترهای عام زیر استفاده کنید:

• علامت سوال (؟) - جایگزین هر کاراکتری می شود.
• ستاره (*) - جایگزین هر دنباله ای از کاراکترها می شود.

استفاده از Wildcards در توابع VPR می تواند در بسیاری از موارد مفید باشد، به عنوان مثال:

• وقتی دقیقاً متنی را که باید پیدا کنید به خاطر نمی آورید.
• وقتی می خواهید کلمه ای را پیدا کنید که بخشی از محتوای یک سلول است. بدان که VPR محتویات سلول را به طور کلی جستجو می کند، گویی این گزینه فعال است کل محتوای سلول را مطابقت دهید (کل سلول) در جستجوی استاندارد اکسل.
• زمانی که یک سلول دارای فضاهای اضافی در ابتدا یا انتهای محتوا باشد. در چنین شرایطی، شما می توانید برای مدت طولانی مغز خود را درگیر کنید و سعی کنید بفهمید که چرا فرمول کار نمی کند.

مثال 1: به دنبال متنی هستید که با کاراکترهای خاصی شروع یا پایان می یابد

فرض کنید می خواهید یک مشتری خاص را در پایگاه داده نشان داده شده در زیر جستجو کنید. نام خانوادگی او را به خاطر نمی آورید، اما می دانید که با "ack" شروع می شود. در اینجا فرمولی وجود دارد که کار را به خوبی انجام می دهد:

=VLOOKUP("ack*",$A$2:$C$11,1,FALSE)

=ВПР("ack*";$A$2:$C$11;1;ЛОЖЬ)

اکنون که مطمئن شدید نام صحیح را پیدا کرده اید، می توانید از همان فرمول برای یافتن مبلغ پرداختی توسط این مشتری استفاده کنید. برای این کار کافیست آرگومان سوم تابع را تغییر دهید VPR به شماره ستون مورد نظر در مورد ما، این ستون C (سومین در محدوده) است:

=VLOOKUP("ack*",$A$2:$C$11,3,FALSE)

=ВПР("ack*";$A$2:$C$11;3;ЛОЖЬ)

در اینجا چند نمونه دیگر با حروف عام وجود دارد:

~ نامی را پیدا کنید که به "مرد" ختم می شود:

=VLOOKUP("*man",$A$2:$C$11,1,FALSE)

=ВПР("*man";$A$2:$C$11;1;ЛОЖЬ)

~ نامی پیدا کنید که با «ad» شروع و با «پسر» ختم شود:

=VLOOKUP("ad*son",$A$2:$C$11,1,FALSE)

=ВПР("ad*son";$A$2:$C$11;1;ЛОЖЬ)

~ ما اولین نام را در لیست پیدا می کنیم که شامل 5 کاراکتر است:

=VLOOKUP("?????",$A$2:$C$11,1,FALSE)

=ВПР("?????";$A$2:$C$11;1;ЛОЖЬ)

برای عملکرد VPR با wildcards به درستی کار می کرد، به عنوان چهارمین آرگومان که همیشه باید استفاده کنید نادرست (نادرست). اگر محدوده جستجو حاوی بیش از یک مقدار باشد که با عبارات جستجو مطابقت دارد، اولین مقدار یافت شده برگردانده خواهد شد.

مثال 2: حروف عام و مراجع سلولی را در فرمول های VLOOKUP ترکیب کنید

حالا بیایید به مثال کمی پیچیده تر از نحوه جستجو با استفاده از تابع نگاه کنیم VPR بر اساس مقدار در یک سلول تصور کنید که ستون A لیستی از کلیدهای مجوز است و ستون B لیستی از نام هایی است که دارای مجوز هستند. علاوه بر این، شما بخشی (چند کاراکتر) از نوعی کلید مجوز در سلول C1 دارید و می خواهید نام مالک را پیدا کنید.

این کار را می توان با استفاده از فرمول زیر انجام داد:

=VLOOKUP("*"&C1&"*",$A$2:$B$12,2,FALSE)

=ВПР("*"&C1&"*";$A$2:$B$12;2;FALSE)

این فرمول مقدار سلول C1 را در محدوده داده شده جستجو می‌کند و مقدار مربوطه را از ستون B برمی‌گرداند. توجه داشته باشید که در آرگومان اول، قبل و بعد از مرجع سلول از یک کاراکتر آمپرسند (&) برای پیوند دادن رشته متن استفاده می‌کنیم.

همانطور که در شکل زیر مشاهده می کنید، تابع VPR «جرمی هیل» را برمی‌گرداند زیرا کلید مجوز او شامل دنباله‌ای از کاراکترهای سلول C1 است.

توجه داشته باشید که استدلال آرایه جدولی (جدول) در تصویر بالا حاوی نام جدول (جدول 7) به جای تعیین محدوده ای از سلول ها است. این همان کاری است که در مثال قبلی انجام دادیم.

مطابقت دقیق یا تقریبی در تابع VLOOKUP

و در نهایت، اجازه دهید نگاهی دقیق تر به آخرین آرگومان تعیین شده برای تابع داشته باشیم VPR - range_lookup (interval_view). همانطور که در ابتدای درس ذکر شد، این استدلال بسیار مهم است. شما می توانید نتایج کاملاً متفاوتی را در یک فرمول با مقدار آن بدست آورید کد واقعی (درست) یا نادرست (نادرست).

ابتدا بیایید دریابیم که منظور مایکروسافت اکسل از تطابق دقیق و تقریبی چیست.

• اگر استدلال range_lookup (range_lookup) برابر است با نادرست (FALSE)، فرمول به دنبال یک مطابقت دقیق است، یعنی دقیقاً همان مقداری که در آرگومان داده شده است lookup_value (مقدار_جستجو). اگر در ستون اول محدوده tقابل_آرایه (جدول) با دو یا چند مقدار مطابق با آرگومان مواجه می شود lookup_value (search_value)، سپس اولین مورد انتخاب خواهد شد. اگر هیچ منطبقی یافت نشد، تابع یک خطا را گزارش می کند #AT (#N/A). به عنوان مثال، فرمول زیر یک خطا را گزارش می کند #AT (#N/A) اگر مقداری در محدوده A2:A15 وجود نداشته باشد 4:

  =VLOOKUP(4,A2:B15,2,FALSE)

  =ВПР(4;A2:B15;2;ЛОЖЬ)

• اگر استدلال range_lookup (range_lookup) برابر است با کد واقعی (درست)، فرمول به دنبال یک تطابق تقریبی است. به طور دقیق تر، ابتدا تابع VPR به دنبال یک تطابق دقیق می گردد و اگر موردی یافت نشد، یک مورد تقریبی را انتخاب می کند. تطابق تقریبی بزرگترین مقداری است که از مقدار مشخص شده در آرگومان تجاوز نمی کند. lookup_value (مقدار_جستجو).

اگر استدلال range_lookup (range_lookup) برابر است با کد واقعی (درست است) یا مشخص نشده است، سپس مقادیر ستون اول محدوده باید به ترتیب صعودی، یعنی از کوچکترین به بزرگترین، مرتب شوند. در غیر این صورت، عملکرد VPR ممکن است یک نتیجه اشتباه را بازگرداند.

برای درک بهتر اهمیت انتخاب کد واقعی (حقیقت) یا نادرست (FALSE)، بیایید به چند فرمول دیگر با تابع نگاه کنیم VPR و به نتایج نگاه کنید

مثال 1: یافتن تطابق دقیق با VLOOKUP

همانطور که به یاد دارید، برای جستجوی یک مطابقت دقیق، آرگومان چهارم تابع VPR باید مهم باشد نادرست (نادرست).

بیایید از همان مثال اول به جدول برگردیم و بفهمیم کدام حیوان می تواند با سرعت حرکت کند 50 مایل بر ساعت. من معتقدم که این فرمول هیچ مشکلی برای شما ایجاد نمی کند:

=VLOOKUP(50,$A$2:$B$15,2,FALSE)

=ВПР(50;$A$2:$B$15;2;ЛОЖЬ)

توجه داشته باشید که محدوده جستجوی ما (ستون A) شامل دو مقدار است 50 - در سلول ها A5 и A6. فرمول مقدار را از سلول برمی گرداند B5. چرا؟ زیرا زمانی که به دنبال یک تطابق دقیق، تابع VPR از اولین مقدار یافت شده استفاده می کند که با مقدار مورد جستجو مطابقت دارد.

مثال 2: استفاده از VLOOKUP برای یافتن یک تطابق تقریبی

وقتی از تابع استفاده می کنید VPR برای جستجوی یک مطابقت تقریبی، یعنی زمانی که آرگومان range_lookup (range_lookup) برابر است با کد واقعی (TRUE) یا حذف شده است، اولین کاری که باید انجام دهید این است که محدوده را بر اساس ستون اول به ترتیب صعودی مرتب کنید.

این بسیار مهم است زیرا عملکرد VPR بزرگترین مقدار بعدی را بعد از مقدار داده شده برمی گرداند و سپس جستجو متوقف می شود. اگر از مرتب‌سازی صحیح غفلت کنید، با نتایج بسیار عجیب یا پیام خطا مواجه خواهید شد. #AT (#N/A).

اکنون می توانید از یکی از فرمول های زیر استفاده کنید:

=VLOOKUP(69,$A$2:$B$15,2,TRUE) or =VLOOKUP(69,$A$2:$B$15,2)

=ВПР(69;$A$2:$B$15;2;ИСТИНА) or =ВПР(69;$A$2:$B$15;2)

همانطور که می بینید، من می خواهم بفهمم که کدام یک از حیوانات نزدیک ترین سرعت را دارد 69 مایل بر ساعت. و در اینجا نتیجه تابع به من بازگشت VPR:

همانطور که می بینید، فرمول یک نتیجه را نشان داد بزکوهی (آنتلوپ) که سرعت آن 61 مایل در ساعت، اگرچه این لیست نیز شامل می شود یوزپلنگ وحشی (یوزپلنگ) که با سرعت می دود 70 مایل در ساعت، و 70 نزدیکتر به 69 از 61 است، اینطور نیست؟ چرا این اتفاق می افتد؟ از آنجا که تابع VPR هنگام جستجوی یک تطابق تقریبی، بزرگترین مقدار را برمی‌گرداند که از مقدار مورد جستجو بیشتر نباشد.

امیدوارم این مثال‌ها کمی در مورد کار با تابع روشن شود VPR در اکسل، و دیگر به او به عنوان یک فرد خارجی نگاه نمی کنید. حالا بد نیست به طور خلاصه نکات کلیدی مطالبی را که مطالعه کرده ایم تکرار کنیم تا بهتر آن را در حافظه تثبیت کنیم.

VLOOKUP در اکسل - باید این را به خاطر بسپارید!

1. عملکرد VPR اکسل نمی تواند به سمت چپ نگاه کند. همیشه به دنبال مقدار در سمت چپ ترین ستون محدوده ارائه شده توسط آرگومان می گردد آرایه جدولی (جدول).
2. در عمل VPR همه مقادیر حساس به حروف بزرگ و کوچک هستند، یعنی حروف کوچک و بزرگ معادل هستند.
3. اگر مقداری که به دنبال آن هستید کمتر از مقدار حداقل در ستون اول محدوده مورد جستجو است، تابع VPR یک خطا گزارش خواهد کرد #AT (#N/A).
4. اگر آرگومان 3 col_index_num (شماره_ستون) کمتر از 1تابع VPR یک خطا گزارش خواهد کرد #ارزش! (#ارزش!). اگر از تعداد ستون های محدوده بیشتر باشد آرایه جدولی (جدول)، تابع یک خطا را گزارش خواهد کرد #مرجع! (#ارتباط دادن!).
5. از مراجع سلول مطلق در آرگومان استفاده کنید آرایه جدولی (جدول) تا محدوده جستجوی صحیح هنگام کپی فرمول حفظ شود. سعی کنید از محدوده ها یا جداول نامگذاری شده در اکسل به عنوان جایگزین استفاده کنید.
6. هنگام انجام یک جستجوی تقریبی مطابقت، به یاد داشته باشید که اولین ستون در محدوده مورد نظر باید به ترتیب صعودی مرتب شود.
7. در نهایت اهمیت استدلال چهارم را به خاطر بسپارید. از مقادیر استفاده کنید کد واقعی (حقیقت) یا نادرست (FALSE) عمداً و از بسیاری از سردردها خلاص خواهید شد.

در مقالات بعدی آموزش عملکرد ما VPR در اکسل نمونه های پیشرفته تری مانند انجام محاسبات مختلف با استفاده از آن را یاد خواهیم گرفت VPR، استخراج مقادیر از چندین ستون و موارد دیگر. از شما برای خواندن این آموزش متشکرم و امیدوارم هفته آینده دوباره شما را ببینم!